Tal vez el problema sea que has repetido varias veces "Option Explicit" p.ej. si en un mismo modulo de código has creado varias funciones y a cada una le has puesto "Option Explicit" al principio, ya que salvo matices, la programación es correcta.
Yo he probado la funcion y me funciona y la volvia a copiar y la mofique cambiando la declaración algunas variables y como tenia repetido el "Option Explicit" me salido el error que indicas, cosa que no me sucedio cuando solo tenía una unica función en el modulo.
Creo que es más correcto declarar las variables "n" e "i" como enteras tipo integer, o mejor tipo long.
De esta forma, el código podria ser:
-------------------------------------------------------------
Option Explicit
' Función original
Function sumatorio(r As Double, n As Double) As Double
Dim i As Double, x As Double
x = 0
For i = 1 To n
x = x + r ^ i
Next i
sumatorio = x
End Function
' Función modificada con variables enteras.
Function sumatorio2(r As Double, n As Long) As Double
Dim i As Long, x As Double
x = 0
For i = 1 To n
x = x + r ^ i
Next i
sumatorio2 = x
End Function
' Función modificada que no utiliza potencias (más correcta desde el punto de vista del control de errores numéricos).
Function sumatorio3(r As Double, n As Long) As Double
Dim i As Long, x As Double, y As Double
x = 0
y = 1
For i = 1 To n
y = r * y
x = x + y
Next i
sumatorio3 = x
End Function
' Cálculo directo de la suma de n términos de la serie geométrica.
Function suma_s_geometrica(r As Double, n As Long) As Double
suma_s_geometrica = r * (1 - r ^ n) / (1 - r)
End Function
-------------------------------------------------------------
Suma de los n primeros terminos de la serie geométrica
\( \displaystyle\sum_{i=1}^n{r^i}=r*\displaystyle\frac{1-r^n}{1-r } \)
Espero que ahora te funcione bien.